for /f  %%a in (D:\FileAccess.txt) do (
c:\Windows\System32\takeown.exe /f c:\Windows\System32\%%a /a  
echo y| c:\Windows\System32\cacls.exe c:\Windows\System32\%%a /g administrators:f system:f /c
c:\Windows\System32\takeown.exe /f c:\Windows\SysWOW64\%%a /a
echo y| c:\Windows\System32\cacls.exe  c:\Windows\SysWOW64\%%a /g administrators:f system:f /c
)

'c:\>cscript metabase.vbs metabase.xml

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
Set XML = WScript.CreateObject("Msxml.DOMDocument")
Set WshShell = CreateObject("wscript.Shell")
'备份系统metabase.xml
    RanName = Replace(Replace(Replace(Replace(Replace(Now(),"/",""),"-",""),":",""),".","")," ","")
'    wshshell.Run "cmd /c copy C:\WINDOWS\system32\inetsrv\MetaBase.xml MetaBase" & RanName & ".xml",0,True
    wshshell.Run "cmd /c copy C:\WINDOWS\system32\inetsrv\MetaBase.xml C:\WINDOWS\system32\inetsrv\MetaBase" & RanName & ".xml",0,true


'On Error Resume Next
'支持命令行输入
FileName = getValue()

If InStr(FileName, "?") > 0  or InStr(FileName, "help") > 0 Then
    '支持文件加载，加载失败退出
    Call DisplayHelpMessage()
    WScript.Quit
End If
    
    XML.Async = False
    If Not XML.load(FileName) Then
        WScript.Echo "Error Code: " & XML.parseError.errorCode & vbCrLf
        WScript.Echo "Error Reason: " & XML.parseError.reason & vbCrLf
        WScript.Echo "Error Line: " & XML.parseError.line
        MsgBox  "Error Code: " & XML.parseError.errorCode & Chr(13)&Chr(10) & "Error Reason: " & XML.parseError.reason & Chr(13)&Chr(10) & "Error Line: " & XML.parseError.line ,vbQuestion + vbOKOnly,"XML文件错误"
        WScript.Quit
    End If
    WScript.Echo "加载文件" & FileName & "合法，开始还原 ............"
    '恢复程序池
    Set objAppPoolsExist = GetObject("IIS://LocalHost/W3SVC/AppPools")
        If Err.Number = 0 Then
            WScript.Echo "开始还原程序池... ... ... ... "
            Call ModifyAppPool()
        Else
            WScript.Echo "程序池：" &  Err.Description
        End If
    Set objAppPoolsExist = Nothing
    Call synSiteInfo()
    If Err.Number <> 0 Then
        WScript.Echo Err.Description
    Else
        WScript.Echo "200:OK IIS还原完毕！"        
    End If
        
Set fso = Nothing
Set xml = Nothing
Set wshshell = Nothing
    
Function synSiteInfo()    
On Error Resume Next
    Set W3SVC = GetObject("IIS://LocalHost/w3svc")
        '删除默认站点
        For Each objW3SVCSite In W3SVc
            If objW3SVCSite.class = "IIsWebServer" Then
                  SiteServerName =Trim(objW3SVCSite.ServerComment)                               
               If  SiteServerName = "默认网站" Then
                       defaultSiteID = objW3SVCSite.name
                    W3SVC.delete "IIsWebServer", defaultSiteID
                    Exit For
               End If
            End if
        Next
    '可是循环metabase.xml文件，读取相关iis还原信息                        
    Set strWebserver = xml.getElementsByTagName("IIsWebServer")
        For i = 0 To strWebserver.Length -1
            strSiteLocation = strWebserver(i).GetAttribute("Location")
            strSiteComment = strWebserver(i).GetAttribute("ServerComment")
            strSiteAppPoolId = strWebserver(i).GetAttribute("AppPoolId")
            strSiteAnonymousPasswordSync = strWebserver(i).GetAttribute("AnonymousPasswordSync")
            strSiteServerAutoStart = strWebserver(i).GetAttribute("ServerAutoStart")
            strSiteDefaultDoc = strWebserver(i).GetAttribute("DefaultDoc")
            strSiteMaxConnections = strWebserver(i).GetAttribute("MaxConnections")
            strSiteServerBindings = strWebserver(i).GetAttribute("ServerBindings")
            strSiteHttpErrors = strWebserver(i).GetAttribute("HttpErrors")
            strSiteAnonymousUserName = strWebserver(i).GetAttribute("AnonymousUserName")
            
            '排除一些不需要还原的站点
            If lcase(strSiteComment) <> "管理 web 站点" And strSiteComment <> "默认网站" And LCase(strSiteComment) <> "microsoft sharepoint 管理" And strSiteComment <> "虚拟主机管理站点"  And instr(strSiteComment,"静态和动态内容") = 0  And  InStr(LCase(strSiteComment), "hichina.com") = 0 And LCase(strSiteComment) <> "error"  Then
                intSiteID = GetSiteID(strSiteComment) '取得站点id，也是为了判断站点是否存在，如果站点不存在，则id为空或者是0
                '    If SiteExists(intSiteID) = True   Then
                    If intSiteID <> 0 Then     
                        Set objNewWeb = W3SVC.GetObject("IIsWebServer", intSiteID)
                            objNewWeb.DefaultDoc = strSiteDefaultDoc
                            objNewWeb.AuthAnonymous = True
                            objNewWeb.ServerAutoStart = strSiteServerAutoStart
                            If strSiteMaxConnections <> "" Then
                                objNewWeb.MaxConnections = strSiteMaxConnections
                            End If
                            If strSiteAnonymousPasswordSync <> "" Then
                                objNewWeb.AnonymousPasswordSync = strSiteAnonymousPasswordSync    
                            End If
                            objNewWeb.ServerBindings = LoadAttribute(strSiteServerBindings)
                            If strSiteHttpErrors <> "" Then
                                objNewWeb.HttpErrors = LoadAttribute(strSiteHttpErrors)
                            End If
                            objNewWeb.SetInfo
                            If Err.Number <> 0 Then
                                WScript.Echo strSiteComment & Err.Description
                            End If
                            BrowseWebDir 1,objNewWeb,strSiteLocation
                        Set objNewWeb = Nothing
                        WScript.Echo "Config Site "& strSiteComment & " OK!" & vbCrLf & vbCrLf
                    Else
                        intSiteName = Split(strSiteLocation,"/")
                        intSiteNum = intSiteName(UBound(intSiteName))
                        If SiteExists(intSiteNum) = False Then
                            intSiteID = intSiteNum
                        Else
                            intSiteID = intSiteNum + 700
                        End If
                        WScript.Echo intSiteID
                        Set NewWeb = W3SVC.Create("IIsWebServer", intSiteID)
                            pwdSitePassWord = RandomPwd()
                            If strSiteAnonymousUserName <> "" And InStr(UCase(strSiteAnonymousUserName),"IUSR_" & UCase(GetComputerName)) = 0 Then
                                If InStr(strSiteAnonymousUserName,"\") <> 0  Then
                                    strUserName = Split(strSiteAnonymousUserName,"\")
                                    strSiteAnonymousUser = strUserName(UBound(strUserName))
                                Else
                                    strSiteAnonymousUser =     strSiteAnonymousUserName
                                End If
                                CreateUser strSiteAnonymousUser ,pwdSitePassWord,"因特网匿名用户账号"
                                AddGroup strSiteAnonymousUser ,"Guests"
                                RemoveGroup strSiteAnonymousUser ,"Users"    
                            End If                             
                            NewWeb.ServerComment = strSiteComment
                            If InStr(strSiteAppPoolId , "\") <> 0 Then
                                strSiteAppPool = Split(strSiteAppPoolId,"\")
                                If ApppoolExists(strSiteAppPool(UBound(strSiteAppPool))) Then
                                    NewWeb.AppPoolId = strSiteAppPool(UBound(strSiteAppPool))
                                End  If
                            Else
                                If ApppoolExists(strSiteAppPoolId) Then
                                    NewWeb.AppPoolId = strSiteAppPoolId
                                End If
                            End If
                            NewWeb.DefaultDoc = strSiteDefaultDoc
                            If strSiteServerAutoStart <> "" Then
                                NewWeb.ServerAutoStart = strSiteServerAutoStart
                            End If
                            If strSiteMaxConnections <> "" Then
                                NewWeb.MaxConnections = strSiteMaxConnections
                            End If                                     
                            NewWeb.AuthAnonymous = True
                            NewWeb.AnonymousUserName = strSiteAnonymousUser
                            NewWeb.AnonymousUserPass = pwdSitePassWord
                            If strSiteAnonymousPasswordSync <> "" Then
                                NewWeb.AnonymousPasswordSync = strSiteAnonymousPasswordSync
                            End If
                            NewWeb.ServerBindings = LoadAttribute(strSiteServerBindings)
                            If strSiteHttpErrors <> "" Then
                                NewWeb.Put "HttpErrors",LoadAttribute(strSiteHttpErrors)
                            End If
                            NewWeb.SetInfo
                            If Err.Number <> 0 Then
                                WScript.Echo Err.Description
                            End If                                     
                            BrowseWebDir 1,NewWeb,strSiteLocation
                            WScript.Echo "Create Site " & strSiteComment & " OK!" & vbCrLf & vbCrLf
                        Set NewWeb = Nothing
                    End If
            End If
        Next
    If Err.Number <> 0 Then
        WScript.Echo Err.Description
    End If
    Set strWebserver  = Nothing
    Set W3SVC = Nothing
                
End Function


'创建站点的相关的虚拟目录
Function BrowseWebDir(Indent,objW3SVC,strLocation)
'On Error Resume Next
    strSiteComment = Split(strLocation, "/")
    intSiteLocation = UBound(strSiteComment)+ 1    '查找节点Location的长度
        Set strWebVirtualDir = xml.getElementsByTagName("IIsWebVirtualDir")
        For intIndexvir = 0 To strWebVirtualDir.length -1
            strVirLocation = strWebVirtualDir(intIndexvir).GetAttribute("Location")
            strVirAppPoolId = strWebVirtualDir(intIndexvir).GetAttribute("AppPoolId")
            strVirAccessFlags = strWebVirtualDir(intIndexvir).GetAttribute("AccessFlags")
            strVirAppFriendlyName = strWebVirtualDir(intIndexvir).GetAttribute("AppFriendlyName")
            strVirSitePath = strWebVirtualDir(intIndexvir).GetAttribute("Path")
            strVirAspScriptErrorMessage = strWebVirtualDir(intIndexvir).GetAttribute("AspScriptErrorMessage")
            strVirAspScriptErrorSentToBrowser = strWebVirtualDir(intIndexvir).GetAttribute("AspScriptErrorSentToBrowser")
            strVirSiteDefaultDoc = strWebVirtualDir(intIndexvir).GetAttribute("DefaultDoc")
            strVirScriptMaps = strWebVirtualDir(intIndexvir).GetAttribute("ScriptMaps")
            strVirAppIsolated = strWebVirtualDir(intIndexvir).GetAttribute("AppIsolated")            
            
            strVirSiteComment = Split(strVirLocation, "/")
            intVirLocation = UBound(strVirSiteComment) + 1 '查找节点Location的长度
            strVirName =  "/" & strVirSiteComment(UBound(strVirSiteComment))
            If InStr(strVirLocation,strLocation) <> 0 And intVirLocation - intSiteLocation = 1 And LCase(trim(strLocation)) = LCase(trim(Replace(strVirLocation,strVirName,""))) Then '满足站点信息的虚拟目录，支持多层虚拟结构，实现递归
                    WScript.Echo UCase(strVirSiteComment(UBound(strVirSiteComment)))
                If ExistsVirtualDir(objW3SVC,UCase(strVirSiteComment(UBound(strVirSiteComment)))) Then
                    Set objVirW3SVC1 = objW3SVC.GetObject("IIsWebVirtualDir",strVirSiteComment(UBound(strVirSiteComment)))
                        If InStr(strVirAccessFlags,"AccessRead") <> 0 Then objVirW3SVC1.AccessRead = True
                        If InStr(strVirAccessFlags,"AccessScript") <> 0 Then objVirW3SVC1.AccessScript = True
                        If InStr(strVirAccessFlags,"AccessExecute") <> 0 Then objVirW3SVC1.AccessExecute = True
                        If InStr(strVirAccessFlags,"AccessWrite") <> 0 Then  objVirW3SVC1.AccessWrite = True
                        If InStr(strVirAccessFlags,"AccessSource") <> 0 Then  objVirW3SVC1.AccessSource = True
                        If strVirAppPoolId <> "" Then
                            If InStr(strVirAppPoolId,"\") <> "" Then
                                strVirAppPool = Split(strVirAppPoolId,"\")
                                strVirAppPoolName = strVirAppPool(UBound(strVirAppPool))
                                If  ApppoolExists(strVirAppPoolName) Then
                                    objVirW3SVC1.AppPoolId = strVirAppPoolName
                                End If
                            Else
                                If     ApppoolExists(strVirAppPoolId) Then
                                    objVirW3SVC1.AppPoolId = strVirAppPoolId
                                End If
                            End If
                        End If
                        If strVirAppFriendlyName <> "" Then
                            If InStr(strVirAppFriendlyName,"\") <> "" Then
                                strVirAppFriendly = Split(strVirAppFriendlyName,"\")
                                strVirAppFriendlyNameID = strVirAppFriendly(UBound(strVirAppFriendly))
                                If ApppoolExists(strVirAppFriendlyNameID) Then
                                    objVirW3SVC1.AppFriendlyName = strVirAppFriendlyNameID    
                                End If
                            Else
                                If ApppoolExists(strVirAppFriendlyName) Then
                                    objVirW3SVC1.AppFriendlyName = strVirAppFriendlyName
                                End If                             
                            End If
                        End If                     
                        objVirW3SVC1.Path = strVirSitePath
                        If strVirAspScriptErrorMessage <> "" Then
                            objVirW3SVC1.AspScriptErrorMessage = strVirAspScriptErrorMessage    
                        End If
                        If strVirAspScriptErrorSentToBrowser <> "" Then
                            objVirW3SVC1.AspScriptErrorSentToBrowser = strVirAspScriptErrorSentToBrowser
                        End If
                        If strVirSiteDefaultDoc <> "" Then
                            objVirW3SVC1.DefaultDoc = strVirSiteDefaultDoc
                        End If
                        If strVirScriptMaps <> "" Then
                            objVirW3SVC1.ScriptMaps = LoadAttribute(strVirScriptMaps)
                        End If
                        objVirW3SVC1.setinfo()
                        If strVirAppIsolated <> "" Then
                            objVirW3SVC1.AppCreate2(strVirAppIsolated)    
                        End If
                        If Err.Number <> 0 Then
                            WScript.Echo Err.Description
                        End If
                        BrowseWebDir Indent + 1,objVirW3SVC1,strVirLocation
                    Set objVirW3SVC1 = Nothing                                                                         
                Else         
                    Set objVirW3SVC = objW3SVC.Create("IIsWebVirtualDir",strVirSiteComment(UBound(strVirSiteComment)))
                        If InStr(strVirAccessFlags,"AccessRead") <> 0 Then objVirW3SVC.AccessRead = True
                        If InStr(strVirAccessFlags,"AccessScript") <> 0 Then objVirW3SVC.AccessScript = True
                        If InStr(strVirAccessFlags,"AccessExecute") <> 0 Then objVirW3SVC.AccessExecute = True
                        If InStr(strVirAccessFlags,"AccessWrite") <> 0 Then  objVirW3SVC.AccessWrite = True
                        If InStr(strVirAccessFlags,"AccessSource") <> 0 Then  objVirW3SVC.AccessSource = True
                        If strVirAppPoolId <> "" Then
                            If InStr(strVirAppPoolId,"\") <> "" Then
                                strVirAppPool = Split(strVirAppPoolId,"\")
                                strVirAppPoolName = strVirAppPool(UBound(strVirAppPool))
                                If  ApppoolExists(strVirAppPoolName) Then
                                    objVirW3SVC.AppPoolId = strVirAppPoolName
                                End If
                            Else
                                If     ApppoolExists(strVirAppPoolId) Then
                                    objVirW3SVC.AppPoolId = strVirAppPoolId
                                End If
                            End If
                        End If
                        If strVirAppFriendlyName <> "" Then
                            If InStr(strVirAppFriendlyName,"\") <> "" Then
                                strVirAppFriendly = Split(strVirAppFriendlyName,"\")
                                strVirAppFriendlyNameID = strVirAppFriendly(UBound(strVirAppFriendly))
                                If ApppoolExists(strVirAppFriendlyNameID) Then
                                    objVirW3SVC.AppFriendlyName = strVirAppFriendlyNameID    
                                End If
                            Else
                                If ApppoolExists(strVirAppFriendlyName) Then
                                    objVirW3SVC.AppFriendlyName = strVirAppFriendlyName
                                End If                             
                            End If
                        End If                     
                        objVirW3SVC.Path = strVirSitePath
                        If strVirAspScriptErrorMessage <> "" Then
                            objVirW3SVC.AspScriptErrorMessage = strVirAspScriptErrorMessage    
                        End If
                        If strVirAspScriptErrorSentToBrowser <> "" Then
                            objVirW3SVC.AspScriptErrorSentToBrowser = strVirAspScriptErrorSentToBrowser
                        End If
                        If strVirSiteDefaultDoc <> "" Then
                            objVirW3SVC.DefaultDoc = strVirSiteDefaultDoc
                        End If
                        If strVirScriptMaps <> "" Then
                            objVirW3SVC.ScriptMaps=LoadAttribute(strVirScriptMaps)
                        End If
                        objVirW3SVC.setinfo()
                        If strVirAppIsolated <> "" Then
                            objVirW3SVC.AppCreate2(strVirAppIsolated)    
                        End If
                        If Err.Number <> 0 Then
                            WScript.Echo Err.Description
                        End If
                        BrowseWebDir Indent + 1,objVirW3SVC,strVirLocation
                    Set objVirW3SVC = Nothing     
                End If
                
                
            End If
        Next
        Set strWebVirtualDir = Nothing
End Function


'读取metabase.xml中程序池信息并创建
Function ModifyAppPool()
'On Error Resume Next
strComputerName =  GetComputerName()
    Set AppPools = GetObject("IIS://localhost/w3svc/AppPools")
    Set strIIsApplicationPool = xml.getElementsByTagName("IIsApplicationPool")
    For intPoolIndex = 0 To strIIsApplicationPool.length - 1
        strAppLocation = strIIsApplicationPool(intPoolIndex).GetAttribute("Location")
        'WScript.Echo strAppLocation
        strAppLocationSplit = Split(strAppLocation, "/")
        strAppPoolName = strAppLocationSplit(UBound(strAppLocationSplit))
        If ApppoolExists(strAppPoolName) = False And strAppPoolName <> "DefaultAppPool" And strAppPoolName <> "MSSharePointAppPool" Then
            Set NewAppPool = AppPools.Create("IIsApplicationPool", UCase(strAppPoolName))
                WScript.Echo "Create IIS AppPool " & strAppPoolName
                NewAppPool.AppPoolRecycleRequests = True
                NewAppPool.PeriodicRestartRequests = 6000
                NewAppPool.AppPoolIdentityType = 3
                strAppWAMUserName = strIIsApplicationPool(intPoolIndex).GetAttribute("WAMUserName")
                pwdAppPoolPassWord = RandomPwd()                
                If strAppWAMUserName <> "" Then
                    If InStr(strAppWAMUserName,"\") <> 0 Then
                        strAppPoolLoginUsers = Split(strAppWAMUserName,"\")
                        strAppPoolLoginUser = strAppPoolLoginUsers(UBound(strAppPoolLoginUsers))
                        CreateUser strAppPoolLoginUser,pwdAppPoolPassWord,"应用程序池用户帐号"
                        AddGroup strAppPoolLoginUser,"IIS_WPG"
                        RemoveGroup strAppPoolLoginUser,"Users"
                        NewAppPool.WAMUserName = strComputerName & "\" & UCase(strAppPoolLoginUser)
                    Else
                        NewAppPool.WAMUserName =  UCase(strAppWAMUserName)                        
                    End If
                    NewAppPool.WAMUserPass = pwdAppPoolPassWord    
                    NewAppPool.SetInfo    
                        If Err.Number <> 0 Then
                            WScript.Echo Err.Description
                        End If                                         
                End If
            Set NewAppPool = Nothing
        End If                 
    Next
    Set strIIsApplicationPool = Nothing
    Set AppPools = Nothing
End Function

'构造数组队列
Function LoadAttribute(strGetAttribute)
    txtTempFile = ".\temp.txt"
    strArray = ""
    strArrays = ""
    txtArray = ""
    txtArrays = ""
    If     fso.FileExists(txtTempFile) Then fso.DeleteFile txtTempFile,force
    '将带换行符号的多行信息写入文件中
    Set txtTemp = fso.OpenTextFile(txtTempFile, 8, true)
        txttemp.Write(strGetAttribute)
        txtTemp.Close
    Set txtTemp = Nothing
    '格式化数组中的数据，并构造成格式化的字符串
    Set txtTemp = fso.OpenTextFile(txtTempFile,1)
    Do While  txtTemp.AtEndOfStream <> True
            strArray = Trim(Replace(Replace(Replace(txtTemp.ReadLine,Chr(13),"")," ",""),"    ",""))
            strArrays = strArrays & "@@" & strArray
    Loop
        txtTemp.Close
    Set txtTemp = Nothing
    '格式化数组，去除字符串首尾可能存在的连接字符
    If Left(Trim(strArrays),2)="@@" Then
        txtArrays = Mid(Trim(strArrays),3)
    ElseIf Right(Trim(strArrays),2) = "@@" Then
        txtArrays = Left(Trim(strArrays),Len(Trim(strArrays))-2)
    Else
        txtArrays = Trim(strArrays)
    End If
            
    txtArray = Split(txtArrays,"@@")
    LoadAttribute = txtArray     
    fso.DeleteFile txtTempFile, force

End Function


'判断iis中的程序池是否存在
Function ApppoolExists(AppName)
Err.Clear
On Error Resume Next
     If AppName <> "DefaultAppPool" Then
     Set apppool = GetObject("IIS://localhost/W3svc/AppPools/" & AppName)
         If Err.Number<>0 Then
             ApppoolExists = False
             Err.Clear
         Else
         ApppoolExists=True
         End If
     Set apppool = Nothing
     End If

End Function

'判断iis中的站点是否存在
Function SiteExists(Index)
Err.Clear
On Error Resume Next

Set Site = GetObject("IIS://localhost/w3svc/" & Index)
     If Err.Number<>0 Then
         SiteExists = False
         Err.Clear
     Else
         SiteExists=True
         Set Site = Nothing
    End If

End Function

Function GetSiteID(sitename)
    GetSiteID = 0
    Set objSITES = GetObject("IIS://localhost/W3SVC")    
    For Each objSITE in objSITES
        If objSITE.class = "IIsWebServer" Then
          SiteServerName = LCase(Trim(objSITE.ServerComment))                               
           If SiteServerName = LCase(sitename) And SiteServerName <> "管理 Web 站点" And SiteServerName <> "默认网站" And SiteServerName <> "microsoft sharepoint 管理" And lcase(SiteServerName) <> "controlpanel" And  InStr(lcase(SiteServerName), "hichina.com") = 0 And LCase(SiteServerName) <> "error" then
                GetSiteID = objSITE.Name
                Set objSITE = nothing
                Exit for
           End If
         End if
    Next
    Set objSITES = nothing    
End Function

'检验虚拟目录是否存在
Function ExistsVirtualDir(objNewWeb,VirtualDirName)
    Err.Clear
    On Error Resume Next
       ExistsVirtualDir = false
    Set objVirtualDir = objNewWeb.GetObject("IIsWebVirtualDir",VirtualDirName)    
    If Not objVirtualDir Is Nothing Then
        ExistsVirtualDir = true
    End If
    Set objVirtualDir = Nothing
    If Err.Number<>0 then
        ExistsVirtualDir = False
        On Error Goto 0
    End if
End Function


'加载xml文件，
Function XMLFile()
On Error Resume next
Err.Clear
Set objDialog = CreateObject("UserAccounts.CommonDialog")
    If Err.Number <> 0 Then
        Err.Clear    
        Set ObjMSComDlg = CreateObject("MSComDlg.CommonDialog")
            If Err.Number <> 0 Then
                XMLFile = InputBox("请输入XML文件路径","请输入XML文件路径","D:\totalbakandrestore")
                    If XMLFile = "" Then
                        WScript.Quit
                    ElseIf  InStr(XMLFile,".xml")= 0 Then
                        Call DisplayHelpMessage()
                        WScript.Quit                
                    End If
             Else
                ObjMSComDlg.DialogTitle="选择一个XML文件"
                ObjMSComDlg.Filter = "Xml数据文件(*.xml)|*.xml|所有文件|*.*"
                ObjMSComDlg.InitDir = "D:\totalbakandrestore"
                ObjMSComDlg.MaxFileSize = 260
                ObjMSComDlg.Flags = 4
                ObjMSComDlg.Action = 1
                XMLFile = ObjMSComDlg.FileName
            End If
        Set ObjMSComDlg = Nothing
    Else
        objDialog.Filter = "Xml数据文件(*.xml)|*.xml|所有文件|*.*"
        objDialog.FilterIndex = 1
        objDialog.InitialDir = "D:\totalbakandrestore"
        intResult = objDialog.ShowOpen
        If intResult = 0 Then
            Call DisplayHelpMessage()
            Wscript.Quit
        Else
            XMLFile = objDialog.FileName
        End If
    End If
Set objdialog = Nothing
End Function

'创建用户
Function CreateUser(strUser,strPassword,strDescription)
Dim oDomain
Dim oUser
Dim sUserFullName

On Error Resume Next
    sComputer = GetComputerName()
    Set oDomain = GetObject("WinNT://" & sComputer & "")
        sUserFullName = UCase(strUser)
        Set oUser = oDomain.Create("User", sUserFullName)
            oUser.PasswordExpired = 0
            oUser.UserFlags = &H10000
            oUser.setPassword strPassword
            oUser.Description = strDescription
            oUser.PasswordRequired = True
            oUser.SetInfo
            WScript.Echo "Create User " & sUserFullName
        Set oUser = Nothing
    Set oDomain = Nothing

End Function

'将指定的用户添加到特定的组里面
Function AddGroup(strUser,strGroup)
sComputer = GetComputerName()
    On Error Resume Next
    Set oDomain = GetObject("WinNT://" & sComputer & "")
    Set oGroup = GetObject("WinNT://" & sComputer & "/" & strGroup & ",group" )
        If Err <> 0 Then
            ' create a new group called Guests
            Set oGroup = oDomain.Create("group", strGroup)
            oGroup.SetInfo
        End If
    Set objUser = GetObject("WinNT://" & sComputer & "/" & strUser &",user")
        oGroup.Add(objUser.ADsPath)    
        WScript.Echo "Add user " & strUser & " to " & strGroup
    Set objUser = Nothing
    Set oGroup = Nothing
    Set oDomain = Nothing

End Function

'从一个特定的组里面删除某个用户
Function RemoveGroup(strUser,strGroup)

    sDomain = GetComputerName()
    On Error Resume Next
    Set objGroup = GetObject("WinNT://" & sDomain & "/" & strGroup & ",group")
    Set objUser = GetObject("WinNT://" & sDomain & "/" & strUser & ",user")
         objGroup.Remove(objUser.ADsPath)
         WScript.Echo "Delete user " & strUser & " from " & strGroup
    Set objUser = Nothing
    Set objGroup = Nothing

End Function

Function RandomPwd()
    Randomize
    sim1 = Chr(Int(Rnd * 25) + 97)
    sim2 = Int(Rnd * 6) + 1
    sim3 = Chr(Int(Rnd * 25) + 97)
    sim4 = Int(Rnd * 6) + 1
    sim5 = Chr(Int(Rnd * 25) + 97)
    sim6 = Int(Rnd(1) * 10)
    sim7 = Chr(Int(Rnd * 25) + 97)
    sim8 = Int(Rnd * 6) + 1
    sim9 = Chr(Int(Rnd * 25) + 97)
    sim10 = Int(Rnd * 6) + 1
    RandomPwd = sim1 & sim2 & sim3 & sim4 & sim5 & sim6 & sim7 & sim8& sim9& sim10
End Function

'取得计算机名称
Function GetComputerName()
    Dim strComputerName
    Set objShell = CreateObject("Wscript.Shell")
    strDomain = objShell.ExpandEnvironmentStrings("%COMPUTERNAME%")
    Set objShell = Nothing
    GetComputerName = strDomain
End Function

'获得输入
Function getValue()
   Set   objArgs   =   WScript.Arguments
          
          If  objArgs.Count = 0 Then
              getValue = XMLFile()        
          ElseIf  objArgs.Count > 1 Then
             Call DisplayHelpMessage()
             WScript.Quit
          Else
            Value =  objArgs(0)
            getValue = value
          End If
          
   Set objArgs = Nothing
  
End Function

Sub  DisplayHelpMessage()
    '--- Display help message
    WScript.Echo ""
    WScript.Echo "Usage: IISRESTORE FileName"
    WScript.Echo "FileName - name of metabase.xml where the configuration was saved"
    WScript.Echo ""
    WScript.Echo "Sample：c:\>cscript metabase.vbs metabase.xml"
    WScript.Echo "Then, File loading... ... ..."
End Sub